# Copyright 2025-2026 Narta Xaymar Dirks <info@xaymar.com>
#
# Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following conditions are met:
#
# 1. Redistributions of source code must retain the above copyright notice, this list of conditions and the following disclaimer.
#
# 2. Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following disclaimer in the documentation and/or other materials provided with the distribution.
#
# 3. Neither the name of the copyright holder nor the names of its contributors may be used to endorse or promote products derived from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS “AS IS” AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

# Require the latest CMake version.
cmake_minimum_required(VERSION 4.2.1)

project("room")

#--------------------------------------------------------------------------------#
# Project
#--------------------------------------------------------------------------------#

file(GLOB_RECURSE _INCLUDE FOLLOW_SYMLINKS CONFIGURE_DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/pub/*")
source_group(TREE "${CMAKE_CURRENT_SOURCE_DIR}/pub" PREFIX "Public" FILES ${_INCLUDE})

file(GLOB_RECURSE _SOURCE FOLLOW_SYMLINKS CONFIGURE_DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/priv/*")
source_group(TREE "${CMAKE_CURRENT_SOURCE_DIR}/priv" PREFIX "Private" FILES ${_SOURCE})

add_executable(${PROJECT_NAME} MACOSX_BUNDLE)

set_target_properties(${PROJECT_NAME} PROPERTIES
	# Always generate position independent code.
	POSITION_INDEPENDENT_CODE ON

	# Set C++ Standard and Extensions
	C_STANDARD 17
	C_STANDARD_REQUIRED ON
	CXX_STANDARD 20
	CXX_STANDARD_REQUIRED ON
	CXX_EXTENSIONS OFF

	# Remove prefix from generated files.
	PREFIX ""
	IMPORT_PREFIX ""

	# Never treat warnings as errors.
	COMPILE_WARNING_AS_ERROR OFF
)

target_sources(${PROJECT_NAME}
	PRIVATE
		${_SOURCE}
	PUBLIC
		${_INCLUDE}
)

target_include_directories(${PROJECT_NAME}
	PRIVATE "priv"
	PUBLIC "pub"
	# Very dumb fix to get wolfSSL to play nice. Why is it extracting the openssl stuff into a subdirectory?
	PRIVATE $<TARGET_PROPERTY:wolfssl::wolfssl,INTERFACE_INCLUDE_DIRECTORIES>/wolfssl
	PRIVATE $<TARGET_PROPERTY:wolfssl::wolfssl,INTERFACE_INCLUDE_DIRECTORIES>
)

target_link_libraries(${PROJECT_NAME}
	PRIVATE wolfssl::wolfssl
	PRIVATE asio::asio
	PRIVATE websocketpp::websocketpp
	PRIVATE zlib-ng::zlib
	PRIVATE nlohmann_json::nlohmann_json
	PRIVATE badaix::jsonrpcpp
)

target_compile_definitions(${PROJECT_NAME}
	PRIVATE	_WEBSOCKETPP_CPP11_STL_
)

if(ENABLE_SSL AND wolfssl_FOUND)
	target_compile_definitions(${PROJECT_NAME}
		PRIVATE	ARCHIPELAGO_ENABLE_SSL
	)
endif()
if(ENABLE_COMPRESSION AND zlib-ng_FOUND)
	target_compile_definitions(${PROJECT_NAME}
		PRIVATE	ARCHIPELAGO_ENABLE_COMPRESSION
	)
endif()

if(WIN32)
	# Disable/Enable a ton of things.
	target_compile_definitions(${PROJECT_NAME} PRIVATE
		# Microsoft Visual C++:
		#- No secure CRT warnings.
		PRIVATE _CRT_SECURE_NO_WARNINGS
		#- Properly align objects when std::align is used.
		PRIVATE _ENABLE_EXTENDED_ALIGNED_STORAGE

		# Target Windows 10 (adjust later?).
		PRIVATE _WIN32_WINNT=0x0A00
	)
endif()